/*
*	Damage Render TDM
*
*				      by GordonFreeman
*			    http://www.lambda-force.org/
*/

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta_util>

#define m_pPlayer	28
#define m_iId		30

new g_maxplayers,particle
new sound,aparticle

new impact_sounds[][] = {
	"weapons/electro4.wav",
	"weapons/electro5.wav",
	"weapons/electro6.wav"
}

public plugin_precache(){
	for(new i;i<sizeof impact_sounds;++i)
		precache_sound(impact_sounds[i])
		
	particle = precache_model("sprites/blueflare2.spr")
}
	
public plugin_init(){
	register_plugin("Damage Render TDM","0.4","GordonFreeman")
	
	register_cvar("damage_render_tdm","0.4",FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_SPONLY)
	
	register_cvar("drtdm_sound","1")
	register_cvar("drtdm_particle","1")
	
	g_maxplayers = get_maxplayers()
}

public plugin_cfg(){
	// stop plugin, if there is not tdm with no ff
	if(!(get_cvar_num("mp_teamplay")&&!get_cvar_num("mp_friendlyfire")))
		pause("ac","Damage Render TDM")
	
	// register ham hooks
	RegisterHam(Ham_TraceAttack,"player","player_traceattack")	// for fire style weapons (block blood)
	RegisterHam(Ham_TakeDamage,"player","player_takedamage")	// for entity based weapons
	
	sound = get_cvar_num("drtdm_sound")
	aparticle = get_cvar_num("drtdm_particle")
}

public player_traceattack(victim,inflictor){
	if(!(0<inflictor<=g_maxplayers))
		return HAM_IGNORED
	
	// check teams
	if(get_user_team(inflictor)!=get_user_team(victim))
		return HAM_IGNORED
	
	// show effects
	remove_task(victim)				// reset
	update_PlayerRender(victim,inflictor,1)		// render
	set_task(0.5,"remove_PlayerRender",victim)	// reset render
		
	return HAM_SUPERCEDE				// block blood
}

public player_takedamage(victim,inflictor,attacker){
	if(!(0<attacker<=g_maxplayers))
		return HAM_IGNORED
		
	if(get_user_team(attacker)!=get_user_team(victim)||victim==attacker)
		return HAM_IGNORED
	
	remove_task(victim)
	update_PlayerRender(victim,attacker,1)
	set_task(0.5,"remove_PlayerRender",victim)
		
	return HAM_SUPERCEDE
}

public remove_PlayerRender(id)
	if(pev_valid(id))
		update_PlayerRender(id,0,0)

public update_PlayerRender(id,attacker,renderstyle){
	if(!renderstyle){
		fm_set_user_rendering(id,kRenderFxNone,0,0,0,kRenderNormal,0)
		
		return PLUGIN_CONTINUE
	}
	
	static color[3],origin[3]
	
	get_user_origin(id,origin)
	
	switch(get_user_team(id)){
		case 1: color = {80,80,255}
		case 2: color = {255,80,80}
		case 3: color = {200,200,80}
		case 4: color = {80,200,80}
		default: color = {0,0,0}
	}
	
	// sounds
	if(sound)
		emit_sound(id,CHAN_BODY,impact_sounds[random(2)],0.5,ATTN_NORM,0,PITCH_NORM)
	
	// make some particles
	if(aparticle){
		message_begin(MSG_ONE,SVC_TEMPENTITY,origin,attacker)
		write_byte(TE_SPRITETRAIL)
		write_coord(origin[0])
		write_coord(origin[1])
		write_coord(origin[2])
		write_coord(origin[0])
		write_coord(origin[1])
		write_coord(origin[2]+10)
		write_short(particle)
		write_byte(3)
		write_byte(1)
		write_byte(1)
		write_byte(random_num(10,20))
		write_byte(5)
		message_end()
	}	
	
	fm_set_user_rendering(id,kRenderFxGlowShell,color[0],color[1],color[2],kRenderNormal,100)	// rendering
	
	return PLUGIN_CONTINUE
}