/*	AMX Mod X script.

	Strong Password Generator by Zetex.

	Info:
		Plugin allows to easily set random password on server.
		To use command player should have "k" access flag (ADMIN_PASSWORD).

	Commands:
		amx_setpassword - generate random password and set it to sv_password cvar if sv_password is empty, and clear sv_password if it contains password.

	ChangeLog:
		v1.0 [2014.07.05]
			Initial release.
*/

#pragma semicolon 1
#pragma ctrlchar '\'

#include <amxmodx>
#include <amxmisc>
#include <password_generator>

#define AUTHOR "Zetex"
#define PLUGIN "Strong Password Generator"
#define VERSION "1.0"

#define PASSWORD_LENGTH 8

new pcvar_sv_password;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_concmd("amx_setpassword", "cmdSetPassword", ADMIN_PASSWORD, "- generate random password");
	pcvar_sv_password = get_cvar_pointer("sv_password");
}

public cmdSetPassword(id, level, cid) {
	if (!cmd_access(id, level, cid, 1))
		return PLUGIN_HANDLED;

	new password[PASSWORD_LENGTH + 1];
	get_pcvar_string(pcvar_sv_password, password, charsmax(password));

	if (!password[0]) {
		new length = generate_strong_password(password, charsmax(password));
		console_print(id, "Server password: %s\nPassword length: %i", password, length);
	} else {
		password[0] = 0;
		console_print(id, "Server password removed");
	}

	set_pcvar_string(pcvar_sv_password, password);
	return PLUGIN_HANDLED;
}